0. Código

>	restart; with(plots): with(geometry):

Warning, the name changecoords has been redefined

>

cbk  := 'color = black, filled = true':                      #black cwh  := 'color = white, filled = true':                      #white cy   := 'color = COLOR(RGB, .1, .85, .1), filled = true':     #light yellow cy1  := 'color = COLOR(RGB, .8, .7,  .0), filled = true':     #yellow cy2  := 'color = COLOR(RGB, .8, .6,  .0), filled = true':     #yellow (orangish) cc   := 'color = COLOR(RGB, .78, .52, .0), filled = true':   #coral (orange/yellow) cdb  := 'color = COLOR(RGB, .30, .20, .1), filled = true':   #dark brown cdb2  := 'color = COLOR(RGB, .45, .30, .15), filled = true': #dark brown 50% brighter cdb3  := 'color = COLOR(RGB, .6, .40, .2), filled = true':   #dark brown 100% brighter cdb4  := 'color = COLOR(RGB, .75, .50, .25), filled = true': #dark brown 150% brighter cdb5  := 'color = COLOR(RGB, .85, .70, .5), filled = true':  #dark brown  brighter cgr   := 'color = COLOR(RGB, .6, .65, .6), filled = true': cgr2  := 'color = COLOR(RGB, .35, .38, .35), filled = true': cgr4  := 'color = COLOR(RGB, .6, .90, .62), filled = true':  #light green co  := 'color = COLOR(RGB, .9, .5, .1), filled = true': co2 := 'color = COLOR(RGB, .8, .6, .1), filled = true': cr  := 'color = COLOR(RGB, .9, .2, .1), filled = true': cr2 := 'color = COLOR(RGB, .9, .4, .2), filled = true': cy  := 'color = COLOR(RGB, .8, .8, .1), filled = true': cg  := 'color = COLOR(RGB, .35, .6, .35), filled = true': cg2 := 'color = COLOR(RGB, .5, .75, .5), filled = true': cb  := 'color = COLOR(RGB, .5, .4, .8), filled = true': cb2 := 'color = COLOR(RGB, .3, .2, .8), filled = true': csb := 'color = COLOR(RGB, .3,.4, .9), filled = true': cgr := 'color = COLOR(RGB, .6, .65, .6), filled = true': cgr2 := 'color = COLOR(RGB, .35, .38, .35), filled = true':

>

lr2 := 'color = red, thickness = 2': lb2 := 'color = COLOR(RGB, .3,.4, .9), thickness = 2': lg2 := 'color = COLOR(RGB, .35, .7, .35), thickness = 2': lw2 := 'color = white,  thickness = 2': lk2 := 'color = black,  linestyle = 3':   ldb2   := 'color = COLOR(RGB, .30, .20, .1), thickness = 2': ldb42  := 'color = COLOR(RGB, .85, .70, .5), thickness = 2': ly     := 'color = COLOR(RGB, .8, .6, .0), thickness = 2, linestyle = 3':   lgy    := 'color = COLOR(RGB, .4, .4, .4), thickness = 2':   lgy2   := 'color = COLOR(RGB, .65, .65, .65), thickness = 2':

>	an := 'axes = none':

>	point( A, [-3, - 2]):   point( B, [ 8, - 1]): point( C, [ 0,   5]): triangle( T, [A,B,C]):

>	point( A2, [  0, 0]):   point( B2, [ 10, 0]): point( C2, [  0, 8]): triangle( T2, [A2,B2,C2]):

>	point( A3, [  0, 0]):   point( B3, [ 10, 0]): point( C3, [  -5, 8]): triangle( T3, [A3,B3,C3]):

>	point( A4, [-5,   1]):   point( B4, [ 9, - 1]): point( C4, [ 0,   5]): triangle( T4, [A4,B4,C4]):

>	#draw( [T(cdb),T2(cdb5),T3(cdb3),T4(cdb2)] );

>

  1. Ângulos Bissetriz                >   Incenter

Um triângulo tem três ângulos. Cada ângulo pode ser bifurcado por uma linha

>	bisector(bi1,A,T):  bisector(bi2,B,T):  bisector(bi3,C,T):

>	draw( [T(cdb), bi1(ldb42)]);

Maravilhoso essas três linhas divididas. Essa divisão dessas três linhas é o incenter, o qual é o centro do círculo inscrito.

>	draw( [T(cdb), bi1(ldb42),bi2(ldb42),bi3(ldb42)]);

Mais maravilhoso é que é sempre possível desenhar um círculo o qual está centrado nesse ponto, o qual se adapta dentro do triângulopara que ele toque cada um dos três lados. Isso é chamado  "inscribed circle" para o triângulo. E isso porque nós chamamos esse ponto de  "no centro" porque ele é o centrodo círculo.  Aqui está uma visão com ângulos bissetrizdemonstrando que eles se dividem no centro do círculo inscrito.

>	incircle( inT, T): draw( [inT(cdb3), T(cdb), bi1(ldb42),bi2(ldb42),bi3(ldb42), center(inT)],an);

>	draw( [ inT, center(inT),bi1,bi2,bi3,T], color=[red,black,blue,coral,coral,coral], an );

Aqui estão outros triângulos
.

>	draw( T3(cdb),an);

>	bisector(bi1,A3,T3):  bisector(bi2,B3,T3):  bisector(bi3,C3,T3): incircle( inT, T3): draw( [inT(cdb3), T3(cdb), bi1(ldb42),bi2(ldb42),bi3(ldb42), center(inT)], an);

>	bisector(bi1,A2,T2):  bisector(bi2,B2,T2):  bisector(bi3,C2,T2): incircle( inT, T2): draw( [inT(cdb3), T2(cdb), bi1(ldb42),bi2(ldb42),bi3(ldb42), center(inT)],an);

  2. Bissetriz Perpendicular    >   Circumcenter

Uma bissetriz perpendicular  de um segmento é outra linha a qual divide em duas partes iguais o segmento e é ao mesmo tempo perpendicular a ele. Cada lado do triângulo é um segmento de linha, e portanto pode ser dividido.

>	PerpenBisector( p1, A, B):  PerpenBisector( p2, B, C):  PerpenBisector( p3, A, C): segment( base, A, B):   draw( [T(cb), p1(ly), base(lr2) ],an);

>	segment( base, B, C):   draw( [T(cb), p2(ly), base(lr2) ],an);

>	segment( base, A, C):   draw( [T(cb), p3(ly), base(lr2) ],an);

Quando as bissetrizes perpendiculares são desenhadas para os três lados, elas se dividem em um único ponto chamado

circumcenter .

>	draw( [p1(ly),p2(ly),p3(ly),T(cb)],an);

O circumcenter deve ser o centro do círculo o qual cisrcunscreve o triângulo. Aqui está um panorama com o ângulo bissetriz demonstrando que ele divide o centro do círculo inscrito.

>	circumcircle( outT, T): draw( [ center(outT), p1(ly),p2(ly),p3(ly),T(cb),outT(cb2)],an);

Aqui estão outros exemplos. Observe que o circumcenter está dentro do triângulo acima, mas neste próximo exemplo

>	PerpenBisector( p1, A3, B3):  PerpenBisector( p2, B3, C3):  PerpenBisector( p3, A3, C3): circumcircle( outT, T3): draw( [ center(outT), p1(ly),p2(ly),p3(ly),T3(cb),outT(cb2)],an);

Um triângulo retângulo tem o seu circumcenter na hipotenusa - consistente com a propriedade dos semi-círculos e triângulos inscritos

>	PerpenBisector( p1, A2, B2):  PerpenBisector( p2, B2, C2):  PerpenBisector( p3, A2, C2): circumcircle( outT, T2): draw( [ center(outT), p1(ly),p2(ly),p3(ly),T2(cb),outT(cb2)],an);

>	PerpenBisector( p1, A4, B4):  PerpenBisector( p2, B4, C4):  PerpenBisector( p3, A4, C4): circumcircle( outT, T4): draw( [ center(outT), p1(ly),p2(ly),p3(ly),T4(cb),outT(cb2)],an);

  3. Comparando o Círculo Inscribed ao Círculo Circumscribed

Nós temo svisto que cada triângulo  tem um círculo inscribed e um círculo circumscribed. Como seria se nós plotássemos ambos de uma vez? Eles teriam o mesmo centro? Vamos ver ambos no mesmo gráfico.

>

bisector(bi1,A,T):  bisector(bi2,B,T):  bisector(bi3,C,T):  incircle( inT,T): PerpenBisector( p1,A,B):  PerpenBisector( p2,B,C):  PerpenBisector( p3,A,C): circumcircle( outT, T): draw( [center(inT),center(outT), inT(cb),T(cwh),         bi1(lw2),bi2(lw2),bi3(lw2),p1(ly),p2(ly),p3(ly), outT(cb2)],an);

>	draw( [center(inT),center(outT), inT(cb),T(cwh), outT(cb2)],an);

 
O círculo menor é o círculo  inscribed e o maior é o circumscribed. Você pode ver que o  incenter e o circumcenters não são os mesmos.

>

bisector(bi1,A3,T3):  bisector(bi2,B3,T3):  bisector(bi3,C3,T3):  incircle( inT,T3): PerpenBisector( p1,A3,B3):  PerpenBisector( p2,B3,C3):  PerpenBisector( p3,A3,C3): circumcircle( outT, T3): draw( [center(inT),center(outT), inT(cb),T3(cwh),         bi1(lw2),bi2(lw2),bi3(lw2),p1(ly),p2(ly),p3(ly), outT(cb2)],an);

>	draw( [center(inT),center(outT), inT(cb),T(cwh), outT(cb2)],an);

>	incircle( inT,T2):      circumcircle( outT, T2): draw( [center(inT),center(outT), inT(cb),T2(cwh), outT(cb2)],an);

>	incircle( inT,T4):      circumcircle( outT, T4): draw( [center(inT),center(outT), inT(cb),T4(cwh), outT(cb2)],an);

Se nós modificarmos essa situação e iniciássemos com dois círculos, você poderia encontrar um único triângulo o qual tenha o círculo menor como o círculo  inscribed, e o maior como circumscribed? E se você recebesse um único ponto no círculo maior o qual fosse o vértice do triângulo...

>	incircle( inT,T2):       circumcircle( outT, T): draw( [inT(color=navy),outT(color=navy) ],axes = none);

  4. Medianas                          >   Centroid

Uma mediana de um triângulo é uma linha a qual conecta um vértice com o ponto central do lado oposto. Observe que uma mediana não é geralmente um ângulo bissetriz ou uma bissetriz perpendicular, exceto em casos especiais.

>	median(md1,A,T):  median(md2,B,T):  median(md3,C,T): midpoint(mp,B,C): segment( s1,B,mp):segment( s2,C,mp): draw( [T(co), md1(lk2), mp, s1(lb2), s2(lg2)], an);

Se você observar atentamente, verá que a linha preta é desenhada do vértice do ponto central ao lado oposto. O lado oposto é dividido em duas partes, uma verde e uma azul, e essas partes tem tamanhos iguais. Aqui está outra mediana do mesmo triângulo.

>	midpoint(mp,A,C): segment( s1,A,mp):segment( s2,C,mp): draw( [T(co), md2(lk2), mp, s1(lb2), s2(lg2)], an);

O ponto onde as três medianas se encontram é chamado centroid . Esse é um ponto muito especial porque representa o centro de gravidade do triângulo. Se o triângulo fosse feito de metal ou madeira de mesma espessura, o centroid poderia ser o único ponto onde você poderia balançar o triângulo com a ponta de um único dedo!

>	draw( [T(co), md1(lk2),md2(lk2),md3(lk2)],an);

>	median(md1,A3,T3):  median(md2,B3,T3):  median(md3,C3,T3): draw( [T3(co), md1(lk2),md2(lk2),md3(lk2)],an);

>	median(md1,A2,T2):  median(md2,B2,T2):  median(md3,C2,T2): draw( [T2(co), md1(lk2),md2(lk2),md3(lk2)],an);

>	median(md1,A4,T4):  median(md2,B4,T4):  median(md3,C4,T4): draw( [T4(co), md1(lk2),md2(lk2),md3(lk2)],an);

O centroid tem outra propriedade especial. Ele corta cada mediana em duas partes, uma duas vezes maior do que a outra. Nós podemo sverificar isso. Observe que a distância da  centroid para cada vértice é exatamente duas vezes a distância da centroid para o ponto central.

>	centroid( ct, T):  midpoint( mAB, A, B):  midpoint( mBC, B, C):  midpoint( mAC, A, C):

>	evalf( distance( C, ct)) ;    evalf( distance( mAB, ct)) ; `Twice the second piece is `= 2*%; `Which is the same as the first piece`;

>	evalf( distance( A, ct)) ;     evalf( distance( mBC, ct)) ; `Twice the second piece is `= 2*%; `Which is the same as the first piece`;

>	evalf( distance( B, ct)) ; evalf( distance( mAC, ct)) ; `Twice the second piece is `= 2*%; `Which is the same as the first piece`;

  5. Altitudes                         >   Ortocentro

Uma altitude é um segmento de linha que se extende de um vértice ao lado oposto, ou uma extensão daquele lado oposto, perpendicular a ele. Uma altitude é algo como uma mediana que vai do vértice ao lado oposto, no entanto, ela não passa necessariamente através do ponto central do lado oposto. Muitas vezes, a altitude está localizada fora do círculo.

>	altitude(alt1,A,T):  altitude(alt2,B,T):  altitude(alt3,C,T): draw( [T(cg), alt3(lgy2)],an );

>	draw( [T(cg), alt1(lgy2)],an );

>	draw( [T(cg), alt2(lgy2)],an );

O cruzamento das três altitudes e chamada   ortocentro .

>	draw( [T(cg), alt1(lgy2),alt2(lgy2), alt3(lgy2)],an );

Vamos ver mais alguns exemplos. Alguns dos ortocentros não estão no triângulo.

>	altitude(alt1,A3,T3):  altitude(alt2,B3,T3):  altitude(alt3,C3,T3): orthocenter( oc, T3): draw( [oc, T3(cg), alt1(lgy2),alt2(lgy2), alt3(lgy2)],an );

>	altitude(alt1,A2,T2):  altitude(alt2,B2,T2):  altitude(alt3,C2,T2): orthocenter( oc, T2): draw( [oc, T2(cg), alt1(lgy2),alt2(lgy2), alt3(lgy2)],an );

>	altitude(alt1,A4,T4):  altitude(alt2,B4,T4):  altitude(alt3,C4,T4): orthocenter( oc, T4): draw( [oc, T4(cg), alt1(lgy2),alt2(lgy2), alt3(lgy2)],an );

  6. Tudo Junto Agora  - Compare & Contraste

Nós vimos quatro pontos de concorrência. Como eles se comportam juntos? Vamos desenhar 12 linhas de discussão em um único diagrama

>

bisector(bi1,A,T):  bisector(bi2,B,T):  bisector(bi3,C,T): incircle( inT, T): PerpenBisector( p1,A,B):  PerpenBisector( p2,B,C): PerpenBisector( p3,A,C): circumcircle( outT, T):centroid( ct, T):orthocenter( oc, T): median(md1,A,T):  median(md2,B,T):  median(md3,C,T): altitude(alt1,A,T):  altitude(alt2,B,T):  altitude(alt3,C,T):

>	draw( [  center(inT),center(outT),oc,ct,          bi1,bi2,bi3,                   p1(ly),p2(ly),p3(ly),          md1(lk2),md2(lk2),md3(lk2),    alt1(lgy2),alt2(lgy2),alt3(lgy2),          inT(cb),T(cwh),outT(cb2) ],an );

bem isso é muito interessante! Vamos olhar para os quatro centros.

>	draw( [  center(inT),center(outT),oc, ct,         inT(cb),T(cwh),outT(cb2) ],an );

>	draw( [  center(inT),center(outT),oc,ct,inT(cy2),T(co)],an );

Como você pode ver, os quatro centros são quatro pontos distintos!

>	incircle( inT, T3):circumcircle( outT, T3):centroid( ct, T3):orthocenter( oc, T3): draw( [  center(inT),center(outT),oc,ct,inT(cy2),T3(co)], an);

>	incircle( inT, T2):circumcircle( outT, T2):centroid( ct, T2):orthocenter( oc, T2): draw( [  center(inT),center(outT),oc,ct,inT(cy2),T2(co)], an);

>	incircle( inT, T4):circumcircle( outT, T4):centroid( ct, T4):orthocenter( oc, T4): draw( [  center(inT),center(outT),oc,ct,inT(cy2),T4(co)], an);

>

>